サンプルを組んでみました。
処理内容、サブルーチン名、変数名は適当なのでお好きに変更して下さい。


# ↓サブルーチン

# 既に出撃済みの味方パイロットの最大、平均レベルを取得
GetPartyLv:
Local num pid
Local cnt = 0
Local mlv = 0
Local plv = 0
ForEach 味方 (出撃 格納)
	Set pid PilotID()
	Set num Level(pid)
	Set mlv Max(mlv,num)
	Incr cnt 1
	Incr plv num
Next
Set 味方最大レベル mlv
Set 味方平均レベル (plv \ cnt)
Return

# Call SetPartyLv party level
# party = 陣営名もしくはグループID (省略不可)
# level = パイロットのレベル (省略不可)
# 
# 既に出撃済みのパイロットを一括でレベル調整
SetPartyLv:
Local pid
Local plv = Args(2)
ForEach Args(1) (出撃 格納)
	Set pid PilotID()
	LevelUp pid (plv - Level(pid))
Next
Return

# ↓使用例

# GetPartyLv で味方の最大、平均レベルを取得
Call GetPartyLv

# Create でユニットを作成する場合は、
# ローカル変数で保存されている「味方最大レベル」もしくは「味方平均レベル」でレベル調整
Create party unit rank pilot (味方最大レベル - 3) x y
Create party unit rank pilot (味方平均レベル - 3) x y

# 既に出撃済みのパイロットを一括でレベル調整する場合
Call SetPartyLv 敵 (味方最大レベル - 3)
Call SetPartyLv 中立 (味方平均レベル - 3)

現状のSRCではＳＰ単体で「残存ＨＰのｎ％」のダメージを与える機能はありません。
ただ、ローカルＳＰとバトルコンフィグ(battle.txt)を用いれば再現は可能だと思います。

サンプルを組んでみました。
もっと細かく設定したい場合はサブルーチンを追加または修正して下さい。
またサブルーチン名適当なので好きに変更して下さい。


# sp.txt
#
# 簡単に言えばＳＰをフラグとして使用
割合ダメージ３０％
非表示, 0, 自分, 攻撃, -, -, -
-
敵の残りＨＰ３０％分のダメージを与える

# battle.txt
#
# ＳＰ「残存ＨＰ３０％ダメージ」を持つユニットの場合、敵の残存ＨＰ３０％のダメージ、それ以外の場合は通常ダメージ
最終ダメージ
EventBattleConfig(攻撃側ユニットＩＤ,防御側ユニットＩＤ,最終値)

# Data\Include.eve　辺りに追記
#
EventBattleConfig:
Local uid1 = Args(1)
Local uid2 = Args(2)
If SpecialPower(uid1,割合ダメージ３０％) = 1 Then
	Return (HP(uid2) * 0.3)
EndIf
Return Args(3)