>>・Globalコマンドで指定しているのに、数値が受け継がれません。
Globalコマンドの指定に不備は見当たらないので、おそらく分岐(Ifコマンド)の不備ではないでしょうか？

(例)

If トモ出番 = 1 Then
	// Launchコマンド記載
Else
	// Createコマンド記載
EndIf


>>・薬草っていうアイテムを数えたいのですが、数値は初期値の０のままでかぞえられません。
Infoに特定キャラの特定アイテムをの装備数を参照する機能はありません。
なので下記�@の様なサブルーチンを用意して、下記�Aの様に実行して下さい。

//  �@  //////////////////////////////////////////
GetItemCount:
// 引数１ ＝ ユニットＩＤ
// 引数２ ＝ アイテム名
Local i
Local uid = Args(1)
Local itm = Args(2)
Local cnt = 0
For i = 1 To CountItem(uid)
	If Item(uid,i) = itm Then
		Inr cnt 1
	EndIf
Next
Return cnt
//  �A  //////////////////////////////////////////
Set 採ってきた薬草 0
Incr 採ってきた薬草 GetItemCount(キャラ, 薬草)
Incr 採ってきた薬草 GetItemCount(アイ, 薬草)
Incr 採ってきた薬草 GetItemCount(ユウ, 薬草)
Incr 採ってきた薬草 GetItemCount(トモ, 薬草)
//////////////////////////////////////////////////


>>・Ｅｓｃａｐｅコマンドで指定しても、ロボットたちが消えてくれません。
>>Escape 帝国兵士(ザコ)
>>Escape 帝国兵士リーダー

この場合は「帝国兵士(ザコ)」と「帝国兵士リーダー」が一体ずつしか撤退しません。
陣営名(「味方」「敵」「中立」「ＮＰＣ」)を指定すれば陣営の全ユニットを撤退させられます。

特定のグループを撤退させたい場合はCreateで作成時にグループＩＤを設定して下記の様に実行すれば撤退できます。

//////////////////////////////////////////////////
ForEach グループＩＤ 出撃
	Escape
Next
//////////////////////////////////////////////////


>>・脱出したら次の道（マップ）に進むというのをやりたいのですが、次のマップが黒くなってしまいます。
単純に考えて「Event04_$(x).map」が存在していないファイルを指定しているからだと思います。

>>Set x
>>For x = 1 To 5
>>x = 1
>>Next

どういった処理を担ってるのかが解りません。
もし実行されると永遠にループし続けると思います。

>>If x < 5 Then
>>
>>If Exフラグ1 = 1 Then

整合性が取れていません。EndIfが必要です。

脱出した際の場所で個別にファイル名指定ではダメなのですか？
共通部分があるのなら、共通部分をサブルーチン化して実行する手もあります。

//////////////////////////////////////////////////
脱出 味方 N:
Call 脱出共通
ChangeMap Event04_1.map
Exit

脱出 味方 S:
Call 脱出共通
ChangeMap Event04_2.map
Exit

脱出 味方 W:
Call 脱出共通
ChangeMap Event04_3.map
Exit

脱出 味方 E:
Call 脱出共通
ChangeMap Event04_4.map
Exit

脱出共通:
//ブランいる
If Exフラグ1 = 1 Then
	Talk キャラ
	やっと抜けた。
	Talk トモ
	油断するなよ。;
	まだ道は続いている。;
	Talk アイ
	そうそう。;
	ティキたちの本拠地まで、まだまだかかるんだから。
	Talk ユウ
	ええ〜っ！！
	End
EndIf
Return
//////////////////////////////////////////////////

>>とやっているのですが、どうしても０にひっかかってしまうようで。

試しに下記の様な処理を行って記述の整合性を確認した所。
2(トモ出番 = 0)→1(トモ出番 = 1)と処理されていました。ので記述的には間違っていないと思います。

思い付く原因としては、
1.Globalコマンドが設定されていない状態でステージを跨いだ。
2.処理前に「トモ出番」が書きえられている。

以上のことが考えられます。一度シナリオを確認してみては如何でしょうか？

//////////////////////////////////////////////////
If トモ出番 = 1 Then
	Talk システム
	1
	End
ElseIf トモ出番 = 0 Then
	Set トモ出番 1
	Talk システム
	2
	End
Else
	Talk システム
	3
	End
EndIf

If トモ出番 = 1 Then
	Talk システム
	1
	End
ElseIf トモ出番 = 0 Then
	Set トモ出番 1
	Talk システム
	2
	End
Else
	Talk システム
	3
	End
EndIf
//////////////////////////////////////////////////


>>で、やってみたのですが、Ｉｎｒにひっかかって数えられませんでした。何かの間違いでしょうか？

Incrコマンドが「Inr」になっていました。

//  訂正版
GetItemCount:
// 引数１ ＝ ユニットＩＤ
// 引数２ ＝ アイテム名
Local i
Local uid = Args(1)
Local itm = Args(2)
Local cnt = 0
For i = 1 To CountItem(uid)
	If Item(uid,i) = itm Then
		Incr cnt 1
	EndIf
Next
Return cnt
//////////////////////////////////////////////////


>>というのを左に脱出したらを４回くらい繰り返して行いたいのです。５回目は敵（ボス）との戦闘です。

下記の様な感じではダメですか？これなら解りやすいと思うのですが。
それと「脱出カウント」は適当に設定したので適当に変更して下さい。

//////////////////////////////////////////////////
脱出 味方 W:
Incr 脱出カウント 1
Switch 脱出カウント
Case 1
	// 脱出1回目のイベント
Case 2
	// 脱出2回目のイベント
Case 3
	// 脱出3回目のイベント
Case 4
	// 脱出4回目のイベント
Case 5
	// 脱出5回目のイベント
EndSw

ChangeMap "Event04_$(脱出カウント).map"
Exit
//////////////////////////////////////////////////


>>If （ザコリーダー）= 2 Then
>>ElseIf 植物モンスター = 1 Then
>>どうしても敵数でやるしかないでしょうか。

えー、推測するに特定ユニットの数によって処理をしたいって事ですか？
でしたら下記の様な感じでどうですか？
まあユニット数によっては処理が重くなってしまいますけど…

//////////////////////////////////////////////////
GetUnitCount:
// 引数１ ＝ 陣営名
// 引数２ ＝ ユニット名
Local i
Local cnt = 0
Local uname = Args(2)
ForEach Args(1) 出撃
	If Info(ユニット, UnitID(), 名称) = uname Then
		Incr cnt 1
	EndIf
Next
Return cnt
//////////////////////////////////////////////////
If GetUnitCount(敵, ザコリーダー) = 2 Then
	//
ElseIf GetUnitCount(敵, 植物モンスター) = 1 Then
	//
Else
	//
EndIf
//////////////////////////////////////////////////

>>エラーは出なかったのですが、シナリオが途中で消えてしまいました。

何度か試しましたが特に問題は無かったです。
なのでGetItemCountを導入している状態で下記を実行してみて下さい。
-1が表示されたあと0以上が表示されればGetItemCount以外の問題です。

//////////////////////////////////////////////////
Set 採ってきた薬草 0
Talk システム
-1
End
Incr 採ってきた薬草 GetItemCount(キャラ, 薬草)
Incr 採ってきた薬草 GetItemCount(アイ, 薬草)
Incr 採ってきた薬草 GetItemCount(ユウ, 薬草)
Incr 採ってきた薬草 GetItemCount(トモ, 薬草)
Talk システム
$(採ってきた薬草)
End
//////////////////////////////////////////////////


>>イベントは普通に動いて、最後にボスが出てきてくれたのですが、そのとたんにマップが変わってボスが消えてしまいました。

ChangeMapの実行タイミングの差なので方法としては、移動前イベントと移動後イベントを分ければ良いだけかと。
設定例を下記に記載しておきます。

>>ClearEventでやったのですが、引数が足りませんとでました。脱出 味方 E　あるいは、ChangeMap"Event04_$(脱出カウント).map"です。
>>その後も動いてくれたんですけど。イベント終わりまでいきました。

ちょっと理解できませんでした。

//////////////////////////////////////////////////
//�@
脱出 味方 W:
Incr 脱出カウント 1
Switch 脱出カウント
Case 1
	// マップ移動前1回目のイベント
Case 2
	// マップ移動前2回目のイベント
Case 3
	// マップ移動前3回目のイベント
Case 4
	// マップ移動前4回目のイベント
Case 5
	// マップ移動前5回目のイベント
EndSw

ChangeMap "Event04_$(脱出カウント).map"

Switch 脱出カウント
Case 1
	// マップ移動後1回目のイベント
Case 2
	// マップ移動後2回目のイベント
Case 3
	// マップ移動後3回目のイベント
Case 4
	// マップ移動後4回目のイベント
Case 5
	// マップ移動後5回目のイベント
EndSw

Exit
//////////////////////////////////////////////////
//�A
脱出 味方 W:
Incr 脱出カウント 1
Switch 脱出カウント
Case 1
	// 1回目の移動前イベント
	ChangeMap "Event04_$(脱出カウント).map"
	// 1回目の移動後イベント
Case 2
	// 2回目の移動前イベント
	ChangeMap "Event04_$(脱出カウント).map"
	// 2回目の移動後イベント
Case 3
	// 3回目の移動前イベント
	ChangeMap "Event04_$(脱出カウント).map"
	// 3回目の移動後イベント
Case 4
	// 4回目の移動前イベント
	ChangeMap "Event04_$(脱出カウント).map"
	// 4回目の移動後イベント
Case 5
	// 5回目の移動前イベント
	ChangeMap "Event04_$(脱出カウント).map"
	// 5回目の移動後イベント
EndSw
Exit
//////////////////////////////////////////////////


>>ユニット名やパイロット名を入れてもその処理を行ってくれません。

こちらも何度か試しましたが特に問題は無かったです。
一応確認ですが愛称で指定してないですよね？　下記の様に設定されていれば「テスト(てすと)」を指定する必要があります。
それと前提としてGetUnitCountは出撃状態のユニットをカウントします。

とりあえずユニットの愛称対応版も用意しておきます。

>>If GetUnitCount(敵, ザコリーダー) = 2 Then
>>ElseIf GetUnitCount(敵, 植物モンスター) = 1 Then

あと気になる所と言えば↑の処理です。
↑は「ザコリーダーがちょうど2体」「植物モンスターがちょうど1体」のいずれかの時に実行する。
と解釈されますが想定道理でしょうか？

//////////////////////////////////////////////////
テスト(てすと)
テスト, てすと, 汎用, 1, 0
//////////////////////////////////////////////////
// ユニット愛称対応版
GetUnitCount:
// 引数１ ＝ 陣営名
// 引数２ ＝ ユニット名称 or ユニット愛称
Local i
Local uid
Local cnt = 0
Local uname = Args(2)
ForEach Args(1) 出撃
	Set uid UnitID()
	If Info(ユニット, uid, 名称) = uname Then
		Incr cnt 1
	ElseIf Info(ユニット, uid, 愛称) = uname Then
		Incr cnt 1
	EndIf
Next
Return cnt
//////////////////////////////////////////////////

>>GetUnitCount

少なくとも私の場合は想定通り機能しているので「ターン 全 敵」の内容を確認しなければ
これ以上アドバイスの仕様がありません。


>>エクセルで言うＩＦＥｒｒｏｒみたいな変数ってありませんか？

IIf関数ではダメですか？

※ヘルプ解説
IIf(条件式,値１,値２)
指定した条件式が成り立つ場合(値が0以外)は値１を、そうでなければ値２を返します。


>>�@アビリティが表示されません。

適当なデータに挿入して確認しましたが普通に表示されました。
なので思いつく限りでは、

�@Disableコマンドで封印されている。
�Aアビリティの定義している箇所が違う。
�Bアビリティ使用条件を満たしていない。

これくらいしか思いつきません。
ですが�Aは定義場所を間違っている場合はエラーが表示されるので原因としては低いかと。


>>�A戦闘アニメが表示されません。

_GetWeaponBmpInfo、_GetEffectBmpInfoは画像情報を取得するためにあるので、
定義されているからと言って全てが戦闘アニメとしては定義されている訳ではありません。
戦闘アニメを定義する場合は「汎用戦闘アニメマニュアル.html」参照したほうが確実だと思います。

手直しすると↓みたいな感じでしょうか。


ビームライフル(準備), 射撃武器 _SelectWPBN(ライフル３) _SelectWPBS(ライフル３)
ビームライフル(攻撃), 小ビーム 赤
ビームライフル(命中), 点打 赤
ライフルで殴る(準備), 射撃武器 _SelectWPBN(ライフル３) _SelectWPBS(ライフル３)

ファイアー(準備), 射撃武器 _SelectWPBN(大型バズーカ) _SelectWPBS(大型バズーカ)
ファイアー(攻撃), 大ビーム 赤
ファイアー(命中), ビームショットガン 赤

ファイアーボール(準備), 火炎弾 赤 
ファイアーボール(攻撃), 火炎弾 赤
ファイアーボール(命中), 炎 赤

※「(準備), 火炎弾」は定義されいますが、実際のところは「(準備), -」と変わりません。

※↓でも良いかも
ビームライフル(準備), ビームライフル 赤 _SelectWPBN(ライフル３) _SelectWPBS(ライフル３)
ビームライフル(攻撃), ビームライフル 赤 _SelectWPBN(ライフル３) _SelectWPBS(ライフル３)
ビームライフル(命中), 点打 赤

ファイアー(準備), バスタービームライフル 赤 _SelectWPBN(大型バズーカ) _SelectWPBS(大型バズーカ)
ファイアー(攻撃), バスタービームライフル 赤 _SelectWPBN(大型バズーカ) _SelectWPBS(大型バズーカ)
ファイアー(命中), ビームショットガン 赤

>>GetUnitCount

�@「ターン 全 敵:」が複数定義されている。
「ターン 全 敵:」を「*ターン 全 敵:」に変更する。

�A演算子が想定と違う。
>>If GetUnitCount(敵, キングザッコ) = 2 Or GetUnitCount(敵, エンペラーザッコ) = 1 Then
キングザッコが3体以上、エンペラーザッコが1体以上ステージに出撃する可能性があるのなら機能しない。
↓なら機能する。
If GetUnitCount(敵, キングザッコ) >= 2 Or GetUnitCount(敵, エンペラーザッコ) >= 1 Then

>>ElseIf GetUnitCount(敵, モンスター) = 1 Then
モンスターが1体以上ステージに出撃する可能性があるのなら機能しない。
↓なら機能する。
ElseIf GetUnitCount(敵, モンスター) >= 1 Then

ただモンスターがユニット愛称もしくはパイロット名称・愛称なら「GetUnitCount」は機能しない。

>>Create 敵 植物モンスター 0 モンスター 1 10 10
複数の同パイロットを出撃させる場合は(ザコ)もしくは(汎用)指定が必須。

�Bユニット・パイロットの名称・愛称対応版に変えてみる。

//////////////////////////////////////////////////
// ユニット・パイロットの名称・愛称対応版
GetUnitCount:
// 引数１ ＝ 陣営名
// 引数２ ＝ ユニット名称 or ユニット愛称
Local i
Local pid uid
Local cnt = 0
Local uname = Args(2)
ForEach Args(1) 出撃
	Set uid UnitID()
	Set pid PilotID()
	If Info(ユニット, uid, 名称) = uname Then
		Incr cnt 1
	ElseIf Info(ユニット, uid, 愛称) = uname Then
		Incr cnt 1
	ElseIf Info(パイロット, pid, 名称) = uname Then
		Incr cnt 1
	ElseIf Info(パイロット, pid, 愛称) = uname Then
		Incr cnt 1
	EndIf
Next
Return cnt
//////////////////////////////////////////////////


>>アニメの設定

基本的なアニメ設定解説「SRC.HLP」→「データの作成」→「戦闘アニメデータ」
基本的なアニメ設定「汎用戦闘アニメマニュアル.html」→左上ウィンドウ「説明書」→左下ウィンドウ「通常アニメ説明書 Top」

解決したようで何よりです。

>>名前を入れてもいいですか？
Readme辺りに記載して頂く分には問題ありません。
もっとも態々記載して頂く様なことでは無いとは思いますけど。