ＳＲＣ質問掲示板Mk2 [One Topic All View / Re[2]: ｢捕獲｣というインクルード / Page: 0]

ＳＲＣ質問掲示板Mk2
(現在過去ログ49 を表示中)

[ 最新記事及び返信フォームをトピックトップへ ]

■9360 / inTopicNo.1)

　｢捕獲｣というインクルード

□投稿者/ たかやん -(2003/07/19(Sat) 17:33:01)

題名のとうり｢SDガンダムGジェネレーション・ネオ｣にあった｢捕獲｣というインクルードを作りたいのですが、インクルードの作り方が分からず困っています。
｢捕獲｣はザコパイロットにのみ有効で敵に隣接すると｢捕獲｣コマンドがでて成功すれば敵ユニットを手に入れることができます。捕獲できる確率は敵のHPが低いほど上がります。このようなインクルードを作ることができますか？教えてください。

引用返信/返信削除キー/

■9364 / inTopicNo.2)

　Re[1]: ｢捕獲｣というインクルード

▲▼■

□投稿者/ 一生十八 -(2003/07/19(Sat) 17:51:43)

どうも。一生十八(いつき　とおや)と申します。

以前、この掲示板で同様の質問があった際に
即興で作ったやつでよろしければ、使ってください。

【使用方法】
・まず、以下のコマンドの羅列を、自作シナリオのDataフォルダ内の
Include.eveにコピー＆ペーストしてください。
・次に、捕獲能力を持たせたいユニットに、以下の武装を追加してください。
捕獲, 0, 1, 1, +0, -, -, -, AAAA, +0, 突固

攻撃味方敵:
攻撃味方中立:
If 対象ユニット使用武器 = "捕獲" Then
#使用された武器が『捕獲』かチェック
If random(100) < damage(相手ユニット) Then
#1～100の乱数が相手の損傷率未満かチェック
#条件を満たせばElseまでが発動
Escape 相手ユニット
Unit unit(相手ユニット) 0
#相手のユニットをEscapeさせ、Escapeしたユニットと同じユニットをランク0で入手
Talk システム
捕獲に成功した
End
#捕獲に成功した事を表示
#ここまでが捕獲成功の一連の流れ
Else
Talk システム
捕獲に失敗した
End
#乱数が損傷率以上だった場合は捕獲失敗と表示
EndIf
Cancel
Finish 対象ユニット
#使用した武器が『捕獲』の場合、本体処理での戦闘を行わず、捕獲の成否に関わらず行動終了とする
EndIf
#それ以外の武器を使用した場合、何もイベントを起こさずExitして普通に戦闘を開始する
Exit

ちなみに、このまま使用すると、ボスランク持ちにも捕獲が適用できるという欠点があります。
そのへんの修正は、シナリオ内でローカルで行なってください。
上記のインクルードを改変されても結構ですので。

解決済み!

引用返信/返信削除キー/

■9369 / inTopicNo.3)

　Re[1]: ｢捕獲｣というインクルード

▲▼■

□投稿者/ がくとへい -(2003/07/19(Sat) 20:39:05)

はじめまして、自分の使っているインクルードから。参考ぐらいにはなればと。

_/_/_/_/_/_/_/

*ユニットコマンド捕獲味方 (ＩＭ <> ON And Party(Info(マップ, (X(対象ユニット) - 1), Y(対象ユニット), ユニットＩＤ)) = 敵 Or Party(Info(マップ, (X(対象ユニット) - 1), Y(対象ユニット), ユニットＩＤ)) = 中立 Or Party(Info(マップ, (X(対象ユニット) + 1), Y(対象ユニット), ユニットＩＤ)) = 敵 Or Party(Info(マップ, (X(対象ユニット) + 1), Y(対象ユニット), ユニットＩＤ)) = 中立 Or Party(Info(マップ, X(対象ユニット), (Y(対象ユニット) - 1), ユニットＩＤ)) = 敵 Or Party(Info(マップ, X(対象ユニット), (Y(対象ユニット) - 1), ユニットＩＤ)) = 中立 Or Party(Info(マップ, X(対象ユニット), (Y(対象ユニット) + 1), ユニットＩＤ)) = 敵 Or Party(Info(マップ, X(対象ユニット), (Y(対象ユニット) + 1), ユニットＩＤ)) = 中立):
捕獲開始画面:
set 捕獲可能機 0

Center X(対象ユニット) Y(対象ユニット)

If Party(Info(マップ, (X(対象ユニット) - 1), Y(対象ユニット), ユニットＩＤ)) = 敵 Or Party(Info(マップ, (X(対象ユニット) - 1), Y(対象ユニット), ユニットＩＤ)) = 中立 Then
PaintPicture Hant.bmp 192 224 透過
HotPoint 捕獲左 192 224 32 32 Unit(Info(マップ, (X(対象ユニット) - 1), Y(対象ユニット), ユニットＩＤ))
set 捕獲可能機 1
EndIf

If Party(Info(マップ, (X(対象ユニット) + 1), Y(対象ユニット), ユニットＩＤ)) = 敵 Or Party(Info(マップ, (X(対象ユニット) + 1), Y(対象ユニット), ユニットＩＤ)) = 中立 Then
PaintPicture Hant.bmp 256 224 透過
HotPoint 捕獲右 256 224 32 32 Unit(Info(マップ, (X(対象ユニット) + 1), Y(対象ユニット), ユニットＩＤ))
set 捕獲可能機 1
EndIf

If Party(Info(マップ, X(対象ユニット), (Y(対象ユニット) - 1), ユニットＩＤ)) = 敵 Or Party(Info(マップ, X(対象ユニット), (Y(対象ユニット) - 1), ユニットＩＤ)) = 中立 Then
PaintPicture Hant.bmp 224 192 透過
HotPoint 捕獲上 224 192 32 32 Unit(Info(マップ, X(対象ユニット), (Y(対象ユニット) - 1), ユニットＩＤ))
set 捕獲可能機 1
EndIf

If Party(Info(マップ, X(対象ユニット), (Y(対象ユニット) + 1), ユニットＩＤ)) = 敵 Or Party(Info(マップ, X(対象ユニット), (Y(対象ユニット) + 1), ユニットＩＤ)) = 中立 Then
PaintPicture Hant.bmp 224 256 透過
HotPoint 捕獲下 224 256 32 32 Unit(Info(マップ, X(対象ユニット), (Y(対象ユニット) + 1), ユニットＩＤ))
set 捕獲可能機 1
EndIf
Refresh

If 捕獲可能機 = 0 Then

Talk システム
捕獲可能な機体がいません
END

Exit
EndIf

Wait Click

If 選択 = "" Then
Mind 対象ユニット覚醒
Move 対象ユニット P_X[対象ユニット] P_Y[対象ユニット]
EN(対象ユニット) = BeforeEN[対象ユニット]
ClearObj
ClearPicture
Exit
EndIf

ClearObj
ClearPicture

Center X(対象ユニット) Y(対象ユニット)

If 選択 = 捕獲左 Then
被捕獲機体 = Info(マップ, (X(対象ユニット) - 1), Y(対象ユニット), ユニットＩＤ)
ElseIf 選択 = 捕獲右 Then
被捕獲機体 = Info(マップ, (X(対象ユニット) + 1), Y(対象ユニット), ユニットＩＤ)
ElseIf 選択 = 捕獲上 Then
被捕獲機体 = Info(マップ, X(対象ユニット), (Y(対象ユニット) - 1), ユニットＩＤ)
ElseIf 選択 = 捕獲下 Then
被捕獲機体 = Info(マップ, X(対象ユニット), (Y(対象ユニット) + 1), ユニットＩＤ)

EndIf

捕獲確率 = Damage(被捕獲機体) + ((Info(対象ユニット,レベル) * 3) - (Info(被捕獲機体,レベル) * 3))

Switch Info(被捕獲機体,サイズ)
Case SS
捕獲確率 = (捕獲確率 * 15) \ 10
Case S
捕獲確率 = (捕獲確率 * 12) \ 10
Case L
捕獲確率 = (捕獲確率 * 8) \ 10
Case LL
捕獲確率 = (捕獲確率 * 5) \ 10
Case XL
捕獲確率 = (捕獲確率 * 2) \ 10
EndSw

If Party(Info(マップ, (X(被捕獲機体) - 1), Y(被捕獲機体), ユニットＩＤ)) = 味方 Then
捕獲確率 = (捕獲確率 * 11) \ 10
EndIf
If Party(Info(マップ, (X(被捕獲機体) + 1), Y(被捕獲機体), ユニットＩＤ)) = 味方 Then
捕獲確率 = (捕獲確率 * 11) \ 10
EndIf
If Party(Info(マップ, X(被捕獲機体), (Y(被捕獲機体) - 1), ユニットＩＤ)) = 味方 Then
捕獲確率 = (捕獲確率 * 11) \ 10
EndIf
If Party(Info(マップ, X(被捕獲機体), (Y(被捕獲機体) + 1), ユニットＩＤ)) = 味方 Then
捕獲確率 = (捕獲確率 * 11) \ 10
EndIf

If Info(被捕獲機体,ボスランク) > 0 Or Skill(被捕獲機体,捕獲可能) = 0 Or 捕獲確率 < 0 Then
捕獲確率 = 0
ElseIf 捕獲確率 > 99 Then
捕獲確率 = 99
EndIf

Talk システム
$(Unit(被捕獲機体)) Rank$(Rank(被捕獲機体));<BIG><B>$(捕獲確率)</B></BIG>
END

Confirm 捕獲しますか？
If 選択 = 0 Goto 捕獲開始画面

If Random(100) < 捕獲確率 Then

PlaySound Sword.wav
Wait 5

Talk システム
捕獲成功！
機体……$(Unit(被捕獲機体));Rank……$(Rank(被捕獲機体));入手！
End

Escape 被捕獲機体

Incr 捕獲数 1

捕獲機[捕獲数] = Unit(被捕獲機体)
捕獲格[捕獲数] = Rank(被捕獲機体)

Unset 捕獲した機体

For i = 1 to 捕獲数

捕獲した機体[i] = "$(捕獲機[i])"

Next

Ask 捕獲した機体捕獲表

Else

PlaySound Swing.wav
Wait 5

Talk システム
捕獲失敗！
End

EndIf

Finish 対象ユニット

Exit

*エピローグ:

If 捕獲数 > 0 Then
For i = 1 to 捕獲数

Talk システム
$(捕獲機[i])、入手！
END

Unit 捕獲機[i] 捕獲格[i]

Next
EndIf

Exit

#############################

更にパイロット能力に、

捕獲可能=非表示, 1

という能力を加えれば、そのパイロットの乗っているユニットは捕獲可能になります。

・捕獲の手順

１，ユニットを隣接させてユニットコマンドの『捕獲』を選ぶ。（有効射程は１）
　　（捕獲の確率は被捕獲側のＨＰとパイロット同士の技量差に値します）
２，捕獲したいターゲットを選ぶ。
３，捕獲成功率を確認して、実行するかを選ぶ。
４，捕獲の合否。

最後にエピローグ画面で捕獲した機体を確認できます。

イベントなどで、非ザコパイロットなどに対して捕獲を行いたい場合、またはその逆は以下のアイテムを装備させてください。

捕獲不可能
-, 固定, 専用
特殊能力
捕獲不可能=非表示
非表示
0, 0, 0, 0, 0

捕獲可能
-, 固定, 専用
特殊能力
パイロット能力付加="捕獲可能=非表示"
非表示
0, 0, 0, 0, 0

例：原作に似たＭＫⅡ強奪イベントなど。
Create 敵ガンダムMKⅡ 3 ジェリド＝メサ 18 18 5
Equip ジェリド捕獲可能

なお、BossRank を持っているユニットには捕獲の成功率は０％になります。
また、捕獲確率が高すぎる、もしくは低すぎるという場合は確率の部分をいじってみてください。

では。

引用返信/返信削除キー/

■9372 / inTopicNo.4)

　Re[2]: ｢捕獲｣というインクルード

▲▼■

□投稿者/ たかやん -(2003/07/19(Sat) 22:44:28)

一生十八さん、がくとへいさん、ありがとうございます。
このインクルードを使わせてもらいます。

解決済み!

引用返信/返信削除キー/

トピック内ページ移動 / << 0 >>

このトピックに書きこむ

過去ログには書き込み不可

HOME HELP 新規作成新着記事トピック表示検索新着情報過去ログ

- Child Tree -
- Antispam Version -